Grabar imágenes en diferentes formatos con GdiPlus-X

Esa es una tarea muy fácil para Gdiplus-X:

Grabar imágnes en diferentes formatos en Visual Fox Pro con Gdiplusx

Todos los ejemplos siguientes utilizan la biblioteca Gdiplus-x. Obtenga la última versión estable de Github

do locfile("system.app")

with _screen.system.drawing

   local mybitmap as xfcbitmap
   && create a bitmap object
   mybitmap = .bitmap.new(getpict())

   && save the bitmap in different formats
   mybitmap.save("c:\mypng.png", .imaging.imageformat.png)
   mybitmap.save("c:\mybmp.bmp", .imaging.imageformat.bmp)
   mybitmap.save("c:\mytiff.tif", .imaging.imageformat.tiff)
   mybitmap.save("c:\myjpeg.jpg", .imaging.imageformat.jpeg)
   mybitmap.save("c:\mygif.gif", .imaging.imageformat.gif)

endwith

Por supuesto, puede guardar como jpeg utilizando el parámetro de codificador de compresión de calidad:
La siguiente muestra solicita una imagen y la guarda como JPEG con calidad 25. Pruebe los valores de 0 a 100.

do locfile("system.app")

with _screen.system.drawing

   local mybitmap as xfcbitmap
   local myencoderparameter as xfcencoderparameter
   local myencoderparameters as xfcencoderparameters
   && create a bitmap object based on a bmp file.
   mybitmap = .bitmap.new(getpict("bmp"))

   && create an encoderparameters object.
   && an encoderparameters object has an array of encoderparameter objects
   && in this case, there is only one encoderparameter object in the array.
   myencoderparameters = .imaging.encoderparameters.new(1)

   && save the bitmap as a jpeg file with quality level 25.
   && using an encoder object based on the guid
   && for the quality parameter category.
   myencoderparameter = .imaging.encoderparameter.new(.imaging.encoder.quality, 25)
   myencoderparameters.param.add(myencoderparameter)
   mybitmap.save("c:\myjpeg_025.jpg", .imaging.imageformat.jpeg, myencoderparameters)

endwith

Grabar imágenes en diferentes formatos con GdiPlus-X

https://vfpimaging.blogspot.com/